42. Robustness #

Contents

Robustness

42.1. Overview #

This lecture modifies a Bellman equation to express a decision maker’s doubts about transition dynamics.

His specification doubts make the decision maker want a robust decision rule.

Robust means insensitive to misspecification of transition dynamics.

The decision maker has a single approximating model.

He calls it approximating to acknowledge that he doesn’t completely trust it.

He fears that outcomes will actually be determined by another model that he cannot describe explicitly.

All that he knows is that the actual data-generating model is in some (uncountable) set of models that surrounds his approximating model.

He quantifies the discrepancy between his approximating model and the genuine data-generating model by using a quantity called entropy.

(We’ll explain what entropy means below)

He wants a decision rule that will work well enough no matter which of those other models actually governs outcomes.

This is what it means for his decision rule to be “robust to misspecification of an approximating model”.

This may sound like too much to ask for, but $\dots$ .

$\dots$ a secret weapon is available to design robust decision rules.

The secret weapon is max-min control theory.

A value-maximizing decision maker enlists the aid of an (imaginary) value-minimizing model chooser to construct bounds on the value attained by a given decision rule under different models of the transition dynamics.

The original decision maker uses those bounds to construct a decision rule with an assured performance level, no matter which model actually governs outcomes.

Note

In reading this lecture, please don’t think that our decision maker is paranoid when he conducts a worst-case analysis. By designing a rule that works well against a worst-case, his intention is to construct a rule that will work well across a set of models.

42.1.1. Sets of Models Imply Sets Of Values#

Our “robust” decision maker wants to know how well a given rule will work when he does not know a single transition law $\dots$ .

$\dots$ he wants to know sets of values that will be attained by a given decision rule $F$ under a set of transition laws.

Ultimately, he wants to design a decision rule $F$ that shapes these sets of values in ways that he prefers.

With this in mind, consider the following graph, which relates to a particular decision problem to be explained below

The figure shows a value-entropy correspondence for a particular decision rule $F$ .

The shaded set is the graph of the correspondence, which maps entropy to a set of values associated with a set of models that surround the decision maker’s approximating model.

Here

Value refers to a sum of discounted rewards obtained by applying the decision rule $F$ when the state starts at some fixed initial state $x_{0}$ .
Entropy is a nonnegative number that measures the size of a set of models surrounding the decision maker’s approximating model.
- Entropy is zero when the set includes only the approximating model, indicating that the decision maker completely trusts the approximating model.
- Entropy is bigger, and the set of surrounding models is bigger, the less the decision maker trusts the approximating model.

The shaded region indicates that for all models having entropy less than or equal to the number on the horizontal axis, the value obtained will be somewhere within the indicated set of values.

Now let’s compare sets of values associated with two different decision rules, $F_{r}$ and $F_{b}$ .

In the next figure,

The red set shows the value-entropy correspondence for decision rule $F_{r}$ .
The blue set shows the value-entropy correspondence for decision rule $F_{b}$ .

The blue correspondence is skinnier than the red correspondence.

This conveys the sense in which the decision rule $F_{b}$ is more robust than the decision rule $F_{r}$ .

more robust means that the set of values is less sensitive to increasing misspecification as measured by entropy.

Notice that the less robust rule $F_{r}$ promises higher values for small misspecifications (small entropy).

(But it is more fragile in the sense that it is more sensitive to perturbations of the approximating model)

Below we’ll explain in detail how to construct these sets of values for a given $F$ , but for now $\dots$ .

Here is a hint about the secret weapons we’ll use to construct these sets

We’ll use some min problems to construct the lower bounds.
We’ll use some max problems to construct the upper bounds.

We will also describe how to choose $F$ to shape the sets of values.

This will involve crafting a skinnier set at the cost of a lower level (at least for low values of entropy).

42.1.2. Inspiring Video#

If you want to understand more about why one serious quantitative researcher is interested in this approach, we recommend Lars Peter Hansen’s Nobel lecture.

42.1.3. Other References#

Our discussion in this lecture is based on

[HS00]
[HS08]

using LinearAlgebra, Statistics

42.2. The Model #

For simplicity, we present ideas in the context of a class of problems with linear transition laws and quadratic objective functions.

To fit in with our earlier lecture on LQ control, we will treat loss minimization rather than value maximization.

To begin, recall the infinite horizon LQ problem, where an agent chooses a sequence of controls ${u_{t}}$ to minimize

(42.1)#

\sum_{t = 0}^{\infty} β^{t} {x_{t}^{'} R x_{t} + u_{t}^{'} Q u_{t}}

subject to the linear law of motion

(42.2)#

x_{t + 1} = A x_{t} + B u_{t} + C w_{t + 1}, t = 0, 1, 2, \dots

As before,

$x_{t}$ is $n \times 1$ , $A$ is $n \times n$
$u_{t}$ is $k \times 1$ , $B$ is $n \times k$
$w_{t}$ is $j \times 1$ , $C$ is $n \times j$
$R$ is $n \times n$ and $Q$ is $k \times k$

Here $x_{t}$ is the state, $u_{t}$ is the control, and $w_{t}$ is a shock vector.

For now we take ${w_{t}} := {w_{t}}_{t = 1}^{\infty}$ to be deterministic — a single fixed sequence.

We also allow for model uncertainty on the part of the agent solving this optimization problem.

In particular, the agent takes $w_{t} = 0$ for all $t \geq 0$ as a benchmark model, but admits the possibility that this model might be wrong.

As a consequence, she also considers a set of alternative models expressed in terms of sequences ${w_{t}}$ that are “close” to the zero sequence.

She seeks a policy that will do well enough for a set of alternative models whose members are pinned down by sequences ${w_{t}}$ .

Soon we’ll quantify the quality of a model specification in terms of the maximal size of the expression $\sum_{t = 0}^{\infty} β^{t + 1} w_{t + 1}^{'} w_{t + 1}$ .

42.3. Constructing More Robust Policies #

If our agent takes ${w_{t}}$ as a given deterministic sequence, then, drawing on intuition from earlier lectures on dynamic programming, we can anticipate Bellman equations such as

J_{t - 1} (x) = min_{u} {x^{'} R x + u^{'} Q u + β J_{t} (A x + B u + C w_{t})}

(Here $J$ depends on $t$ because the sequence ${w_{t}}$ is not recursive)

Our tool for studying robustness is to construct a rule that works well even if an adverse sequence ${w_{t}}$ occurs.

In our framework, “adverse” means “loss increasing”.

As we’ll see, this will eventually lead us to construct the Bellman equation.

(42.3)#

J (x) = min_{u} max_{w} {x^{'} R x + u^{'} Q u + β [J (A x + B u + C w) - θ w^{'} w]}

Notice that we’ve added the penalty term $- θ w^{'} w$ .

Since $w^{'} w = ‖ w ‖^{2}$ , this term becomes influential when $w$ moves away from the origin.

The penalty parameter $θ$ controls how much we penalize the maximizing agent for “harming” the minimizing agent.

By raising $θ$ more and more, we more and more limit the ability of maximizing agent to distort outcomes relative to the approximating model.

So bigger $θ$ is implicitly associated with smaller distortion sequences ${w_{t}}$ .

42.3.1. Analyzing the Bellman equation#

So what does $J$ in (42.3) look like?

As with the ordinary LQ control model, $J$ takes the form $J (x) = x^{'} P x$ for some symmetric positive definite matrix $P$ .

One of our main tasks will be to analyze and compute the matrix $P$ .

Related tasks will be to study associated feedback rules for $u_{t}$ and $w_{t + 1}$ .

First, using matrix calculus, you will be able to verify that

(42.4)#

\begin{array}{r} \begin{aligned} max_{w} & {(A x + B u + C w)^{'} P (A x + B u + C w) - θ w^{'} w} \\ = (A x + B u)^{'} D (P) (A x + B u) \end{aligned} \end{array}

where

(42.5)#

D (P) := P + P C (θ I - C^{'} P C)^{- 1} C^{'} P

and $I$ is a $j \times j$ identity matrix. Substituting this expression for the maximum into (42.3) yields

(42.6)#

x^{'} P x = min_{u} {x^{'} R x + u^{'} Q u + β (A x + B u)^{'} D (P) (A x + B u)}

Using similar mathematics, the solution to this minimization problem is $u = - F x$ where $F := (Q + β B^{'} D (P) B)^{- 1} β B^{'} D (P) A$ .

Substituting this minimizer back into (42.6) and working through the algebra gives $x^{'} P x = x^{'} B (D (P)) x$ for all $x$ , or, equivalently,

P = B (D (P))

where $D$ is the operator defined in (42.5) and

B (P) := R - β^{2} A^{'} P B (Q + β B^{'} P B)^{- 1} B^{'} P A + β A^{'} P A

The operator $B$ is the standard (i.e., non-robust) LQ Bellman operator, and $P = B (P)$ is the standard matrix Riccati equation coming from the Bellman equation — see this discussion.

Under some regularity conditions (see [HS08]), the operator $B \circ D$ has a unique positive definite fixed point, which we denote below by $\hat{P}$ .

A robust policy, indexed by $θ$ , is $u = - \hat{F} x$ where

(42.7)#

\hat{F} := (Q + β B^{'} D (\hat{P}) B)^{- 1} β B^{'} D (\hat{P}) A

We also define

(42.8)#

\hat{K} := (θ I - C^{'} \hat{P} C)^{- 1} C^{'} \hat{P} (A - B \hat{F})

The interpretation of $\hat{K}$ is that $w_{t + 1} = \hat{K} x_{t}$ on the worst-case path of ${x_{t}}$ , in the sense that this vector is the maximizer of (42.4) evaluated at the fixed rule $u = - \hat{F} x$ .

Note that $\hat{P}, \hat{F}, \hat{K}$ are all determined by the primitives and $θ$ .

Note also that if $θ$ is very large, then $D$ is approximately equal to the identity mapping.

Hence, when $θ$ is large, $\hat{P}$ and $\hat{F}$ are approximately equal to their standard LQ values.

Furthermore, when $θ$ is large, $\hat{K}$ is approximately equal to zero.

Conversely, smaller $θ$ is associated with greater fear of model misspecification, and greater concern for robustness.

42.4. Robustness as Outcome of a Two-Person Zero-Sum Game #

What we have done above can be interpreted in terms of a two-person zero-sum game in which $\hat{F}, \hat{K}$ are Nash equilibrium objects.

Agent 1 is our original agent, who seeks to minimize loss in the LQ program while admitting the possibility of misspecification.

Agent 2 is an imaginary malevolent player.

Agent 2’s malevolence helps the original agent to compute bounds on his value function across a set of models.

We begin with agent 2’s problem.

42.4.1. Agent 2’s Problem#

Agent 2

knows a fixed policy $F$ specifying the behavior of agent 1, in the sense that $u_{t} = - F x_{t}$ for all $t$
responds by choosing a shock sequence ${w_{t}}$ from a set of paths sufficiently close to the benchmark sequence ${0, 0, 0, \dots}$

A natural way to say “sufficiently close to the zero sequence” is to restrict the summed inner product $\sum_{t = 1}^{\infty} w_{t}^{'} w_{t}$ to be small.

However, to obtain a time-invariant recursive formulation, it turns out to be convenient to restrict a discounted inner product

(42.9)#

\sum_{t = 1}^{\infty} β^{t} w_{t}^{'} w_{t} \leq η

Now let $F$ be a fixed policy, and let $J_{F} (x_{0}, w)$ be the present-value cost of that policy given sequence $w := {w_{t}}$ and initial condition $x_{0} \in R^{n}$ .

Substituting $- F x_{t}$ for $u_{t}$ in (42.1), this value can be written as

(42.10)#

J_{F} (x_{0}, w) := \sum_{t = 0}^{\infty} β^{t} x_{t}^{'} (R + F^{'} Q F) x_{t}

where

(42.11)#

x_{t + 1} = (A - B F) x_{t} + C w_{t + 1}

and the initial condition $x_{0}$ is as specified in the left side of (42.10).

Agent 2 chooses $w$ to maximize agent 1’s loss $J_{F} (x_{0}, w)$ subject to (42.9).

Using a Lagrangian formulation, we can express this problem as

max_{w} \sum_{t = 0}^{\infty} β^{t} {x_{t}^{'} (R + F^{'} Q F) x_{t} - β θ (w_{t + 1}^{'} w_{t + 1} - η)}

where ${x_{t}}$ satisfied (42.11) and $θ$ is a Lagrange multiplier on constraint (42.9).

For the moment, let’s take $θ$ as fixed, allowing us to drop the constant $β θ η$ term in the objective function, and hence write the problem as

max_{w} \sum_{t = 0}^{\infty} β^{t} {x_{t}^{'} (R + F^{'} Q F) x_{t} - β θ w_{t + 1}^{'} w_{t + 1}}

or, equivalently,

(42.12)#

min_{w} \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t} + β θ w_{t + 1}^{'} w_{t + 1}}

subject to (42.11).

What’s striking about this optimization problem is that it is once again an LQ discounted dynamic programming problem, with $w = {w_{t}}$ as the sequence of controls.

The expression for the optimal policy can be found by applying the usual LQ formula (see here).

We denote it by $K (F, θ)$ , with the interpretation $w_{t + 1} = K (F, θ) x_{t}$ .

The remaining step for agent 2’s problem is to set $θ$ to enforce the constraint (42.9), which can be done by choosing $θ = θ_{η}$ such that

(42.13)#

β \sum_{t = 0}^{\infty} β^{t} x_{t}^{'} K (F, θ_{η})^{'} K (F, θ_{η}) x_{t} = η

Here $x_{t}$ is given by (42.11) — which in this case becomes $x_{t + 1} = (A - B F + C K (F, θ)) x_{t}$ .

42.4.2. Using Agent 2’s Problem to Construct Bounds on the Value Sets#

42.4.2.1. The Lower Bound#

Define the minimized object on the right side of problem (42.12) as $R_{θ} (x_{0}, F)$ .

Because “minimizers minimize” we have

R_{θ} (x_{0}, F) \leq \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t}} + β θ \sum_{t = 0}^{\infty} β^{t} w_{t + 1}^{'} w_{t + 1},

where $x_{t + 1} = (A - B F + C K (F, θ)) x_{t}$ and $x_{0}$ is a given initial condition.

This inequality in turn implies the inequality

(42.14)#

R_{θ} (x_{0}, F) - θ e n t \leq \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t}}

where

e n t := β \sum_{t = 0}^{\infty} β^{t} w_{t + 1}^{'} w_{t + 1}

The left side of inequality (42.14) is a straight line with slope $- θ$ .

Technically, it is a “separating hyperplane”.

At a particular value of entropy, the line is tangent to the lower bound of values as a function of entropy.

In particular, the lower bound on the left side of (42.14) is attained when

(42.15)#

e n t = β \sum_{t = 0}^{\infty} β^{t} x_{t}^{'} K (F, θ)^{'} K (F, θ) x_{t}

To construct the lower bound on the set of values associated with all perturbations $w$ satisfying the entropy constraint (42.9) at a given entropy level, we proceed as follows:

For a given $θ$ , solve the minimization problem (42.12).
Compute the minimizer $R_{θ} (x_{0}, F)$ and the associated entropy using (42.15).
Compute the lower bound on the value function $R_{θ} (x_{0}, F) - θ e n t$ and plot it against $e n t$ .
Repeat the preceding three steps for a range of values of $θ$ to trace out the lower bound.

Note

This procedure sweeps out a set of separating hyperplanes indexed by different values for the Lagrange multiplier $θ$ .

42.4.2.2. The Upper Bound#

To construct an upper bound we use a very similar procedure.

We simply replace the minimization problem (42.12) with the maximization problem.

(42.16)#

V_{\tilde{θ}} (x_{0}, F) = max_{w} \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t} - β \tilde{θ} w_{t + 1}^{'} w_{t + 1}}

where now $\tilde{θ} > 0$ penalizes the choice of $w$ with larger entropy.

(Notice that $\tilde{θ} = - θ$ in problem (42.12))

Because “maximizers maximize” we have

V_{\tilde{θ}} (x_{0}, F) \geq \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t}} - β \tilde{θ} \sum_{t = 0}^{\infty} β^{t} w_{t + 1}^{'} w_{t + 1}

which in turn implies the inequality

(42.17)#

V_{\tilde{θ}} (x_{0}, F) + \tilde{θ} e n t \geq \sum_{t = 0}^{\infty} β^{t} {- x_{t}^{'} (R + F^{'} Q F) x_{t}}

where

e n t \equiv β \sum_{t = 0}^{\infty} β^{t} w_{t + 1}^{'} w_{t + 1}

The left side of inequality (42.17) is a straight line with slope $\tilde{θ}$ .

The upper bound on the left side of (42.17) is attained when

(42.18)#

e n t = β \sum_{t = 0}^{\infty} β^{t} x_{t}^{'} K (F, \tilde{θ})^{'} K (F, \tilde{θ}) x_{t}

To construct the upper bound on the set of values associated all perturbations $w$ with a given entropy we proceed much as we did for the lower bound.

For a given $\tilde{θ}$ , solve the maximization problem (42.16).
Compute the maximizer $V_{\tilde{θ}} (x_{0}, F)$ and the associated entropy using (42.18).
Compute the upper bound on the value function $V_{\tilde{θ}} (x_{0}, F) + \tilde{θ} e n t$ and plot it against $e n t$ .
Repeat the preceding three steps for a range of values of $\tilde{θ}$ to trace out the upper bound.

42.4.2.3. Reshaping the set of values#

Now in the interest of reshaping these sets of values by choosing $F$ , we turn to agent 1’s problem.

42.4.3. Agent 1’s Problem#

Now we turn to agent 1, who solves

(42.19)#

min_{{u_{t}}} \sum_{t = 0}^{\infty} β^{t} {x_{t}^{'} R x_{t} + u_{t}^{'} Q u_{t} - β θ w_{t + 1}^{'} w_{t + 1}}

where ${w_{t + 1}}$ satisfies $w_{t + 1} = K x_{t}$ .

In other words, agent 1 minimizes

(42.20)#

\sum_{t = 0}^{\infty} β^{t} {x_{t}^{'} (R - β θ K^{'} K) x_{t} + u_{t}^{'} Q u_{t}}

subject to

(42.21)#

x_{t + 1} = (A + C K) x_{t} + B u_{t}

Once again, the expression for the optimal policy can be found here — we denote it by $\tilde{F}$ .

42.4.4. Nash Equilibrium#

Clearly the $\tilde{F}$ we have obtained depends on $K$ , which, in agent 2’s problem, depended on an initial policy $F$ .

Holding all other parameters fixed, we can represent this relationship as a mapping $Φ$ , where

\tilde{F} = Φ (K (F, θ))

The map $F \mapsto Φ (K (F, θ))$ corresponds to a situation in which

agent 1 uses an arbitrary initial policy $F$
agent 2 best responds to agent 1 by choosing $K (F, θ)$
agent 1 best responds to agent 2 by choosing $\tilde{F} = Φ (K (F, θ))$

As you may have already guessed, the robust policy $\hat{F}$ defined in (42.7) is a fixed point of the mapping $Φ$ .

In particular, for any given $θ$ ,

$K (\hat{F}, θ) = \hat{K}$ , where $\hat{K}$ is as given in (42.8)
$Φ (\hat{K}) = \hat{F}$

A sketch of the proof is given in the appendix.

42.5. The Stochastic Case #

Now we turn to the stochastic case, where the sequence ${w_{t}}$ is treated as an iid sequence of random vectors.

In this setting, we suppose that our agent is uncertain about the conditional probability distribution of $w_{t + 1}$ .

The agent takes the standard normal distribution $N (0, I)$ as the baseline conditional distribution, while admitting the possibility that other “nearby” distributions prevail.

These alternative conditional distributions of $w_{t + 1}$ might depend nonlinearly on the history $x_{s}, s \leq t$ .

To implement this idea, we need a notion of what it means for one distribution to be near another one.

Here we adopt a very useful measure of closeness for distributions known as the relative entropy, or Kullback-Leibler divergence.

For densities $p, q$ , the Kullback-Leibler divergence of $q$ from $p$ is defined as

D_{K L} (p, q) := \int \ln [\frac{p (x)}{q (x)}] p (x) d x

Using this notation, we replace (42.3) with the stochastic analogue

(42.22)#

J (x) = min_{u} max_{ψ \in P} {x^{'} R x + u^{'} Q u + β [\int J (A x + B u + C w) ψ (d w) - θ D_{K L} (ψ, ϕ)]}

Here $P$ represents the set of all densities on $R^{n}$ and $ϕ$ is the benchmark distribution $N (0, I)$ .

The distribution $ϕ$ is chosen as the least desirable conditional distribution in terms of next period outcomes, while taking into account the penalty term $θ D_{K L} (ψ, ϕ)$ .

This penalty term plays a role analogous to the one played by the deterministic penalty $θ w^{'} w$ in (42.3), since it discourages large deviations from the benchmark.

42.5.1. Solving the Model#

The maximization problem in (42.22) appears highly nontrivial — after all, we are maximizing over an infinite dimensional space consisting of the entire set of densities.

However, it turns out that the solution is tractable, and in fact also falls within the class of normal distributions.

First, we note that $J$ has the form $J (x) = x^{'} P x + d$ for some positive definite matrix $P$ and constant real number $d$ .

Moreover, it turns out that if $(I - θ^{- 1} C^{'} P C)^{- 1}$ is nonsingular, then

(42.23)#

\begin{array}{r} \begin{aligned} max_{ψ \in P} & {\int (A x + B u + C w)^{'} P (A x + B u + C w) ψ (d w) - θ D_{K L} (ψ, ϕ)} \\ = (A x + B u)^{'} D (P) (A x + B u) + κ (θ, P) \end{aligned} \end{array}

where

κ (θ, P) := θ \ln [det (I - θ^{- 1} C^{'} P C)^{- 1}]

and the maximizer is the Gaussian distribution

(42.24)#

ψ = N ((θ I - C^{'} P C)^{- 1} C^{'} P (A x + B u), (I - θ^{- 1} C^{'} P C)^{- 1})

Substituting the expression for the maximum into Bellman equation (42.22) and using $J (x) = x^{'} P x + d$ gives

(42.25)#

x^{'} P x + d = min_{u} {x^{'} R x + u^{'} Q u + β (A x + B u)^{'} D (P) (A x + B u) + β [d + κ (θ, P)]}

Since constant terms do not affect minimizers, the solution is the same as (42.6), leading to

x^{'} P x + d = x^{'} B (D (P)) x + β [d + κ (θ, P)]

To solve this Bellman equation, we take $\hat{P}$ to be the positive definite fixed point of $B \circ D$ .

In addition, we take $\hat{d}$ as the real number solving $d = β [d + κ (θ, P)]$ , which is

(42.26)#

\hat{d} := \frac{β}{1 - β} κ (θ, P)

The robust policy in this stochastic case is the minimizer in (42.25), which is once again $u = - \hat{F} x$ for $\hat{F}$ given by (42.7).

Substituting the robust policy into (42.24) we obtain the worst case shock distribution:

w_{t + 1} \sim N (\hat{K} x_{t}, (I - θ^{- 1} C^{'} \hat{P} C)^{- 1})

where $\hat{K}$ is given by (42.8).

Note that the mean of the worst-case shock distribution is equal to the same worst-case $w_{t + 1}$ as in the earlier deterministic setting.

42.5.2. Computing Other Quantities#

Before turning to implementation, we briefly outline how to compute several other quantities of interest.

42.5.2.1. Worst-Case Value of a Policy#

One thing we will be interested in doing is holding a policy fixed and computing the discounted loss associated with that policy.

So let $F$ be a given policy and let $J_{F} (x)$ be the associated loss, which, by analogy with (42.22), satisfies

J_{F} (x) = max_{ψ \in P} {x^{'} (R + F^{'} Q F) x + β [\int J_{F} ((A - B F) x + C w) ψ (d w) - θ D_{K L} (ψ, ϕ)]}

Writing $J_{F} (x) = x^{'} P_{F} x + d_{F}$ and applying the same argument used to derive (42.23) we get

x^{'} P_{F} x + d_{F} = x^{'} (R + F^{'} Q F) x + β [x^{'} (A - B F)^{'} D (P_{F}) (A - B F) x + d_{F} + κ (θ, P_{F})]

To solve this we take $P_{F}$ to be the fixed point

P_{F} = R + F^{'} Q F + β (A - B F)^{'} D (P_{F}) (A - B F)

and

(42.27)#

d_{F} := \frac{β}{1 - β} κ (θ, P_{F}) = \frac{β}{1 - β} θ \ln [det (I - θ^{- 1} C^{'} P_{F} C)^{- 1}]

If you skip ahead to the appendix, you will be able to verify that $- P_{F}$ is the solution to the Bellman equation in agent 2’s problem discussed above — we use this in our computations.

42.6. Implementation #

The QuantEcon.jl package provides a type called RBLQ for implementation of robust LQ optimal control.

The code can be found on GitHub.

Here is a brief description of the methods of the type

d_operator() and b_operator() implement $D$ and $B$ respectively
robust_rule() and robust_rule_simple() both solve for the triple $\hat{F}, \hat{K}, \hat{P}$ , as described in equations (42.7) – (42.8) and the surrounding discussion
- robust_rule() is more efficient
- robust_rule_simple() is more transparent and easier to follow
K_to_F() and F_to_K() solve the decision problems of agent 1 and agent 2 respectively
compute_deterministic_entropy() computes the left-hand side of (42.13)
evaluate_F() computes the loss and entropy associated with a given policy — see this discussion

42.7. Application #

Let us consider a monopolist similar to this one, but now facing model uncertainty.

The inverse demand function is $p_{t} = a_{0} - a_{1} y_{t} + d_{t}$

where

d_{t + 1} = ρ d_{t} + σ_{d} w_{t + 1}, {w_{t}} \overset{iid}{\sim} N (0, 1)

and all parameters are strictly positive.

The period return function for the monopolist is

r_{t} = p_{t} y_{t} - γ \frac{(y_{t + 1} - y_{t})^{2}}{2} - c y_{t}

Its objective is to maximize expected discounted profits, or, equivalently, to minimize $E \sum_{t = 0}^{\infty} β^{t} (- r_{t})$ .

To form a linear regulator problem, we take the state and control to be

\begin{array}{r} x_{t} = [\begin{array}{c} 1 \\ y_{t} \\ d_{t} \end{array}] and u_{t} = y_{t + 1} - y_{t} \end{array}

Setting $b := (a_{0} - c) / 2$ we define

\begin{array}{r} R = - [\begin{array}{c} 0 & b & 0 \\ b & - a_{1} & 1 / 2 \\ 0 & 1 / 2 & 0 \end{array}] and Q = γ / 2 \end{array}

For the transition matrices we set

\begin{array}{r} A = [\begin{array}{c} 1 & 0 & 0 \\ 0 & 1 & 0 \\ 0 & 0 & ρ \end{array}], B = [\begin{array}{c} 0 \\ 1 \\ 0 \end{array}], C = [\begin{array}{c} 0 \\ 0 \\ σ_{d} \end{array}] \end{array}

Our aim is to compute the value-entropy correspondences shown above.

The parameters are

a_{0} = 100, a_{1} = 0.5, ρ = 0.9, σ_{d} = 0.05, β = 0.95, c = 2, γ = 50.0

The standard normal distribution for $w_{t}$ is understood as the agent’s baseline, with uncertainty parameterized by $θ$ .

We compute value-entropy correspondences for two policies.

The no concern for robustness policy $F_{0}$ , which is the ordinary LQ loss minimizer.
A “moderate” concern for robustness policy $F_{b}$ , with $θ = 0.02$ .

The code for producing the graph shown above, with blue being for the robust policy, is as follows

using QuantEcon, Plots, LinearAlgebra, Interpolations

# model parameters
a_0 = 100
a_1 = 0.5
rho = 0.9
sigma_d = 0.05
beta = 0.95
c = 2
gamma = 50.0
theta = 0.002
ac = (a_0 - c) / 2.0

# Define LQ matrices
R = [0 ac 0;
     ac -a_1 0.5;
     0.0 0.5 0]
R = -R  # For minimization
Q = Matrix([gamma / 2.0]')
A = [1.0 0.0 0.0;
     0.0 1.0 0.0;
     0.0 0.0 rho]
B = [0.0 1.0 0.0]'
C = [0.0 0.0 sigma_d]'

## Functions

function evaluate_policy(theta, F)
    rlq = RBLQ(Q, R, A, B, C, beta, theta)
    K_F, P_F, d_F, O_F, o_F = evaluate_F(rlq, F)
    x0 = [1.0 0.0 0.0]'
    value = -x0' * P_F * x0 .- d_F
    entropy = x0' * O_F * x0 .+ o_F
    return value[1], entropy[1]    # return scalars
end

function value_and_entropy(emax, F, bw, grid_size = 1000)
    if lowercase(bw) == "worst"
        thetas = 1 ./ range(1e-8, 1000, length = grid_size)
    else
        thetas = -1 ./ range(1e-8, 1000, length = grid_size)
    end

    data = zeros(grid_size, 2)

    for (i, theta) in enumerate(thetas)
        data[i, :] = collect(evaluate_policy(theta, F))
        if data[i, 2] >= emax      # stop at this entropy level
            data = data[1:i, :]
            break
        end
    end
    return data
end

## Main

# compute optimal rule
optimal_lq = QuantEcon.LQ(Q, R, A, B, C, zero(B'A), bet = beta)
Po, Fo, Do = stationary_values(optimal_lq)

# compute robust rule for our theta
baseline_robust = RBLQ(Q, R, A, B, C, beta, theta)
Fb, Kb, Pb = robust_rule(baseline_robust)

# Check the positive definiteness of worst-case covariance matrix to
# ensure that theta exceeds the breakdown point
test_matrix = I - (C' * Pb * C ./ theta)[1]
eigenvals, eigenvecs = eigen(test_matrix)
@assert all(x -> x >= 0, eigenvals)

emax = 1.6e6

# compute values and entropies
optimal_best_case = value_and_entropy(emax, Fo, "best")
robust_best_case = value_and_entropy(emax, Fb, "best")
optimal_worst_case = value_and_entropy(emax, Fo, "worst")
robust_worst_case = value_and_entropy(emax, Fb, "worst")

# we reverse order of "worst_case"s so values are ascending
data_pairs = ((optimal_best_case, optimal_worst_case),
              (robust_best_case, robust_worst_case))

egrid = range(0, emax, length = 100)
egrid_data = []
for data_pair in data_pairs
    for data in data_pair
        x, y = data[:, 2], data[:, 1]
        curve = LinearInterpolation(x, y, extrapolation_bc = Line())
        push!(egrid_data, curve.(egrid))
    end
end
plot(egrid, egrid_data, color = [:red :red :blue :blue])
plot!(egrid, egrid_data[1], fillrange = egrid_data[2],
      fillcolor = :red, fillalpha = 0.1, color = :red, legend = :none)
plot!(egrid, egrid_data[3], fillrange = egrid_data[4],
      fillcolor = :blue, fillalpha = 0.1, color = :blue, legend = :none)
plot!(xlabel = "Entropy", ylabel = "Value")

Here’s another such figure, with $θ = 0.002$ instead of $0.02$

Can you explain the different shape of the value-entropy correspondence for the robust policy?

42.8. Appendix #

We sketch the proof only of the first claim in this section, which is that, for any given $θ$ , $K (\hat{F}, θ) = \hat{K}$ , where $\hat{K}$ is as given in (42.8).

This is the content of the next lemma.

Lemma. If $\hat{P}$ is the fixed point of the map $B \circ D$ and $\hat{F}$ is the robust policy as given in (42.7), then

(42.28)#

K (\hat{F}, θ) = (θ I - C^{'} \hat{P} C)^{- 1} C^{'} \hat{P} (A - B \hat{F})

Proof: As a first step, observe that when $F = \hat{F}$ , the Bellman equation associated with the LQ problem (42.11) – (42.12) is

(42.29)#

\tilde{P} = - R - {\hat{F}}^{'} Q \hat{F} - β^{2} (A - B \hat{F})^{'} \tilde{P} C (β θ I + β C^{'} \tilde{P} C)^{- 1} C^{'} \tilde{P} (A - B \hat{F}) + β (A - B \hat{F})^{'} \tilde{P} (A - B \hat{F})

(revisit this discussion if you don’t know where (42.29) comes from) and the optimal policy is

w_{t + 1} = - β (β θ I + β C^{'} \tilde{P} C)^{- 1} C^{'} \tilde{P} (A - B \hat{F}) x_{t}

Suppose for a moment that $- \hat{P}$ solves the Bellman equation (42.29).

In this case the policy becomes

w_{t + 1} = (θ I - C^{'} \hat{P} C)^{- 1} C^{'} \hat{P} (A - B \hat{F}) x_{t}

which is exactly the claim in (42.28).

Hence it remains only to show that $- \hat{P}$ solves (42.29), or, in other words,

\hat{P} = R + {\hat{F}}^{'} Q \hat{F} + β (A - B \hat{F})^{'} \hat{P} C (θ I - C^{'} \hat{P} C)^{- 1} C^{'} \hat{P} (A - B \hat{F}) + β (A - B \hat{F})^{'} \hat{P} (A - B \hat{F})

Using the definition of $D$ , we can rewrite the right-hand side more simply as

R + {\hat{F}}^{'} Q \hat{F} + β (A - B \hat{F})^{'} D (\hat{P}) (A - B \hat{F})

Although it involves a substantial amount of algebra, it can be shown that the latter is just $\hat{P}$ .

(Hint: Use the fact that $\hat{P} = B (D (\hat{P}))$ )